Termostato con Arduino, LM35, relè e display LCD
Realizziamo un termostato con Arduino Uno capace di leggere la temperatura tramite LM35, mostrarla su un display LCD 16×2 e attivare automaticamente un relè quando viene superata una soglia impostata.
Come funziona il termostato
Il sensore LM35 produce una tensione proporzionale alla temperatura. Arduino legge questa tensione attraverso l’ingresso analogico A0 e la converte in gradi Celsius.
Il valore ottenuto viene confrontato con una soglia. Nell’esempio la soglia è impostata a 28 °C: superato questo valore il relè viene attivato, mentre al di sotto viene disattivato.
Materiale necessario
🧰 Kit Arduino consigliato
Un kit completo è utile per avere breadboard, cavetti, resistenze, sensori e molti altri componenti per realizzare questo e numerosi altri progetti Arduino.
👉 Guarda il kit Arduino consigliatoLink di affiliazione Amazon: in qualità di Affiliato Amazon ricevo un guadagno dagli acquisti idonei, senza alcun costo aggiuntivo per te.
📘 Vuoi imparare Arduino passo dopo passo?
Se vuoi approfondire e realizzare progetti più completi, puoi dare un’occhiata anche ai miei libri dedicati ad Arduino. All’interno troverai spiegazioni semplici, schemi chiari e molti progetti pratici pensati per chi parte da zero.
👉 Scopri i miei libri su ArduinoLink di affiliazione Amazon: in qualità di Affiliato Amazon ricevo un guadagno dagli acquisti idonei, senza alcun costo aggiuntivo per te.
Schema con display LCD I2C
Schema del termostato con sensore LM35, relè e display LCD I2C.
Collegamenti principali
| Componente | Collegamento |
|---|---|
| Uscita LM35 | A0 |
| Relè | D7 |
| LCD I2C | Bus I2C di Arduino |
Simulazione Tinkercad
▶️ Apri la simulazione Tinkercad
Come LM35 misura la temperatura
LM35 fornisce una tensione di circa 10 mV per ogni grado Celsius. Per esempio, intorno a 25 °C l’uscita ideale è circa 250 mV.
Arduino legge questa tensione con il convertitore analogico-digitale e la trasforma in temperatura. Nello sketch seguente la conversione viene effettuata esplicitamente partendo dalla tensione letta su A0.
Codice Arduino con display I2C
/*
TERMOSTATO CON ARDUINO, LM35, RELÈ E DISPLAY LCD I2C
LM35 -> A0
Relè -> D7
LCD I2C -> indirizzo 0x27
Il relè viene attivato quando la temperatura supera
la soglia impostata.
*/
#include <LiquidCrystal_I2C.h>
LiquidCrystal_I2C lcd(0x27, 2, 1, 0, 4, 5, 6, 7, 3, POSITIVE);
const int sensorPin = A0;
const int relayPin = 7;
// Temperatura di intervento
const float SOGLIA = 28.0;
// Piccola isteresi per evitare continui ON/OFF vicino alla soglia
const float ISTERESI = 0.5;
bool relayState = false;
void setup() {
lcd.begin(16, 2);
pinMode(relayPin, OUTPUT);
digitalWrite(relayPin, LOW);
Serial.begin(9600);
}
void loop() {
// Lettura del sensore LM35
int reading = analogRead(sensorPin);
// Conversione ADC -> Volt
float tensione = reading * (5.0 / 1023.0);
// LM35: 10 mV per °C
float celsius = tensione * 100.0;
// Termostato con isteresi
if (!relayState && celsius > SOGLIA) {
relayState = true;
}
if (relayState && celsius < (SOGLIA - ISTERESI)) {
relayState = false;
}
digitalWrite(relayPin, relayState ? HIGH : LOW);
// Visualizzazione
lcd.setCursor(0, 0);
lcd.print("Temp: ");
lcd.print(celsius, 1);
lcd.print((char)223);
lcd.print("C ");
lcd.setCursor(0, 1);
lcd.print("RELE: ");
lcd.print(relayState ? "ON " : "OFF");
Serial.print("Temperatura: ");
Serial.print(celsius, 1);
Serial.println(" C");
delay(500);
}
Perché usare un’isteresi
Se il relè venisse acceso esattamente sopra 28 °C e spento esattamente sotto 28 °C, una temperatura oscillante attorno alla soglia potrebbe provocare continui scatti del relè.
Nel codice abbiamo quindi aggiunto una piccola isteresi: il relè si accende sopra 28 °C e si spegne quando la temperatura scende sotto 27,5 °C.
Modificare la temperatura di intervento
La soglia è definita da questa riga:
const float SOGLIA = 28.0;
Per esempio, puoi impostare 24.0, 30.0 o qualsiasi altro valore compatibile con la tua applicazione.
Attivare il relè sopra o sotto la soglia
Il comportamento dipende dall’applicazione. Per comandare una ventola può essere utile accendere il relè quando la temperatura supera la soglia. Per un riscaldatore, invece, normalmente si desidera attivarlo quando la temperatura scende sotto il valore impostato.
Esempio: relè attivo sopra 28 °C.
Esempio: relè attivo sotto 28 °C.
Versione con display LCD 16×2 tradizionale
Il progetto può essere realizzato anche con un LCD 16×2 collegato direttamente ai pin digitali di Arduino, senza interfaccia I2C.
/*
TERMOSTATO CON LCD 16x2 TRADIZIONALE
RS -> D12
E -> D11
D4 -> D5
D5 -> D4
D6 -> D3
D7 -> D2
LM35 -> A0
Relè -> D7
*/
#include <LiquidCrystal.h>
LiquidCrystal lcd(12, 11, 5, 4, 3, 2);
const int sensorPin = A0;
const int relayPin = 7;
const float SOGLIA = 28.0;
void setup() {
lcd.begin(16, 2);
pinMode(relayPin, OUTPUT);
digitalWrite(relayPin, LOW);
}
void loop() {
int reading = analogRead(sensorPin);
float tensione = reading * (5.0 / 1023.0);
float celsius = tensione * 100.0;
lcd.setCursor(0, 0);
lcd.print("Temperatura:");
lcd.setCursor(0, 1);
lcd.print(celsius, 1);
lcd.print((char)223);
lcd.print("C ");
if (celsius > SOGLIA) {
digitalWrite(relayPin, HIGH);
lcd.print("ON ");
} else {
digitalWrite(relayPin, LOW);
lcd.print("OFF");
}
delay(500);
}
Libreria per il display I2C
Per la configurazione I2C mostrata è disponibile la libreria utilizzata nel progetto:
⬇️ Scarica newliquidcrystal_1.3.4
Scarica gli sketch
⬇️ Sketch LCD I2C ⬇️ Sketch LCD 16×2
Attenzione al modulo relè
Molti moduli relè per Arduino possono essere active LOW, cioè si attivano quando il pin di comando viene portato a LOW anziché HIGH. Se il comportamento risulta invertito, verifica il modulo utilizzato e adatta le istruzioni digitalWrite().
Debug rapido
- verifica che LM35 sia collegato correttamente ad A0;
- controlla sul Monitor Seriale la temperatura misurata;
- verifica l’indirizzo I2C del display;
- se il relè funziona al contrario, controlla se il modulo è active LOW;
- se il relè scatta continuamente vicino alla soglia, aumenta leggermente l’isteresi;
- se la temperatura è poco precisa, verifica la tensione di riferimento e il collegamento del sensore.
Varianti del progetto
- aggiungere due pulsanti per modificare la temperatura desiderata;
- salvare la soglia in EEPROM;
- aggiungere un buzzer di allarme;
- comandare una ventola quando la temperatura sale;
- comandare un riscaldatore quando la temperatura scende;
- visualizzare temperatura minima e massima;
- realizzare una versione Wi-Fi con ESP32.
Cosa devi ricordare
- LM35 è collegato all’ingresso analogico A0.
- Il relè viene comandato dal pin D7.
- La soglia dell’esempio è 28 °C.
- Il display mostra temperatura e stato del relè.
- Una piccola isteresi evita commutazioni troppo frequenti.
- Il comportamento può essere invertito per attivare il relè sotto la soglia.
Domande frequenti
Come cambio la temperatura di attivazione?
Modifica il valore della costante SOGLIA nello sketch.
Posso attivare il relè quando la temperatura scende?
Sì. È sufficiente invertire la logica del confronto, soluzione utile quando il relè controlla un sistema di riscaldamento.
Perché il relè si attiva al contrario?
Il tuo modulo potrebbe essere active LOW. Verifica le specifiche del modulo e, se necessario, inverti HIGH e LOW nel codice.
Posso usare un display senza I2C?
Sì. È disponibile anche una versione con LCD 16×2 collegato direttamente ai pin digitali di Arduino.

