Comunicazione wireless tra due Arduino con nRF24L01, DHT11 e display

/*
  TRASMETTITORE TX
  Arduino Uno + nRF24L01 + DHT11

  DHT11 -> A0
  nRF24L01 -> bus SPI di Arduino Uno
  CE  -> D9
  CSN -> D10

  Invia due valori:
  temperature[0] = temperatura
  temperature[1] = umidità
*/

#include <SPI.h>
#include <nRF24L01.h>
#include <RF24.h>
#include <DHT11.h>

// Sensore DHT11
const int DHT_PIN = A0;
DHT11 dht11(DHT_PIN);

// Pacchetto con temperatura e umidità
float temperature[2];

// Radio: CE = D9, CSN = D10
RF24 radio(9, 10);

// Indirizzo del canale logico usato dai due moduli
const uint64_t pipe = 0xE8E8F0F0E1LL;

void setup() {

  // Avvia nRF24L01
  radio.begin();

  // Imposta il modulo come trasmettitore
  radio.openWritingPipe(pipe);
}

void loop() {

  float temp;
  float humi;

  // Legge temperatura e umidità dal DHT11
  dht11.read(humi, temp);

  // Prepara il pacchetto da inviare
  temperature[0] = temp;
  temperature[1] = humi;

  // Trasmette l'intero array
  radio.write(temperature, sizeof(temperature));

  // DHT11 non richiede letture troppo frequenti
  delay(1000);
}

/*
  RICEVITORE RX
  Arduino Uno + nRF24L01 + LCD 16x2 I2C

  nRF24L01:
  CE  -> D9
  CSN -> D10

  Il ricevitore mostra sul display:
  - temperatura
  - umidità
*/

#include <SPI.h>
#include <nRF24L01.h>
#include <RF24.h>
#include <Wire.h>
#include <LCD.h>
#include <LiquidCrystal_I2C.h>

// Display I2C usato nel progetto
LiquidCrystal_I2C lcd(
  0x27,
  2, 1, 0,
  4, 5, 6, 7,
  3, POSITIVE
);

// Array ricevuto via radio:
// [0] temperatura
// [1] umidità
float temperature[2];

// Radio: CE = D9, CSN = D10
RF24 radio(9, 10);

// Deve essere uguale a quello del trasmettitore
const uint64_t pipe = 0xE8E8F0F0E1LL;

void setup() {

  Serial.begin(9600);

  // Avvia il modulo radio
  radio.begin();

  // Configura la pipe di ricezione
  radio.openReadingPipe(1, pipe);

  // Passa in ascolto
  radio.startListening();

  // Avvia LCD
  lcd.begin(16, 2);
  lcd.backlight();

  lcd.clear();
  lcd.print("Umid & temp");
  delay(1000);

  lcd.clear();
  lcd.print("Start.....");
  delay(1000);
}

void loop() {

  // Se è disponibile un nuovo pacchetto...
  if (radio.available()) {

    // Legge temperatura e umidità
    radio.read(temperature, sizeof(temperature));

    // Prima riga: temperatura
    lcd.clear();

    lcd.setCursor(0, 0);
    lcd.print("Temp");

    lcd.setCursor(9, 0);
    lcd.print(temperature[0]);
    lcd.print(" C");

    // Seconda riga: umidità
    lcd.setCursor(0, 1);
    lcd.print("Umid");

    lcd.setCursor(9, 1);
    lcd.print(temperature[1]);
    lcd.print(" %");

    Serial.print("Temperatura: ");
    Serial.print(temperature[0]);
    Serial.print(" C - Umidita: ");
    Serial.print(temperature[1]);
    Serial.println(" %");

    delay(1000);
  }
}

const uint64_t pipe = 0xE8E8F0F0E1LL;